保姆级画廊教程

zxc

[RenPy] 纯文本查看 复制代码

##########################################################################
####这是一个测试版面，无实际图片
##########################################################################

##制作一个基本画廊需要如下操作

##首先，你需要将你设置为cg的图片进行定义

#例如现在定义的是一个基本图片,注意定义的图片路径需要是绝对路径，不然容易出问题
image a1 = "images/a1.jpg"  #这个定义的是在scripts剧本中显示的图片，文本中需要使用a1这个名字进行显示
#当前图片是cg解锁后，点击按钮全屏打开后的图片

image a1_1:
    "images/a1.jpg"
    xysize(200,100)
#这里定义的是a1关联的这张图片的缩略图，如果你不想使用当前的缩略图片，你可以自己使用其他对应大小的图片，
#如果那样做，你可以不用设置图片的大小，当前这个图片是当cg解锁完成后按钮默认显示的图片

#如上我们已经定义好需要的图片，我们还需要准备一个默认未解锁的图片

#然后我们可以开始建立一个py库来实现图片的解锁

init python:
    
    g = Gallery()  #g是我们定义的一个简写Gallery的函数

    g.locked_button = "locked.jpg" #这是定义一个图片未解锁的图片

    #如下开始建立图片库以及关联解锁
    g.button("danw1") #这是建立一个图片标识，使用这个标识能让renpy识别对应关联的图片，这个可以随便起名
    g.unlock_image("a1") #这是建立一个需要解锁的图片，这个图片需要在文本中出现后，自动解锁这个图片，所以名称一定要正确

    #当然这里我们只列举了一个例子，一张图片需要建立一次如上两个g.button和g.unlocked_image,如果你还有更多的图片需要进行
    #画廊解锁，那就继续在当前代码行中添加如上两个参数，值得注意的是代码的缩进

#接下来让我们创建最后一个画廊界面
#当然如下界面需要你在开始菜单中设置一个按钮，使用那个按钮进入到这个界面
screen extra():

    #在这个界面中，我们只需要在设定好框架好的位置添加如下代码即可实现
    add g.make_button("danw1", "a1_1", xalign=0.5, yalign=0.5)
    #这段代码的意思是添加一个按钮，make_button这个函数正常只需要前面两个，第一个是我们在创建图片关联的标识，这个名称需要一样
    #第二个就是我们画廊解锁完成后显示的缩略图



# 当然或许你不太懂，下面将是一个完整的示例

image a1 = "images/a1.jpg"
image a2 = "images/a2.jpg"

image a1_1:
    "images/a1.jpg"
    xysize(200,100)
image a2_1:
    "images/a2.jpg"
    xysize(200,100)

init python:
    
    g = Gallery()

    g.locked_button = "images/locked.jpg"

    g.button("danw1")
    g.unlock_image("a1")

    g.button("danw2")
    g.unlock_image("a2")


screen extra():

    vbox:
        align(0.5,0.5)
        spacing 100
        add g.make_button("danw1","a1_1", xalign=0.5, yalign=0.5)
        add g.make_button("danw2","a2_1", xalign=0.5, yalign=0.5)


label start:

    "这是我们即将显示的第一个cg"

    show a1

    "这是我们显示的第二个cg"

    show a2

    "测试结束，返回画廊即可查看"

    return


#如果你想将所有遇见过的画廊全部上锁，你可以使用引擎界面的《删除持久化数据》进行重置

以上代码工程无图片，需要自己提供图片更改名称自行测试

spica

很好的教程，收藏了

深海里的墨鱼

楼主，你这个"images/a1"不是相对路径吗？绝对路径应该是用反斜杠来分隔的吧
不过教程很好，感谢楼主分享，谢谢大佬

YuMe

很棒，收藏了