【小白求助】关于选择的问题

chenllki

怎么样可以做到当你选择了一次选项对话完后跳回选择区 改变第二次选择对话内容

龙氏

唔，反复读几遍...

比如，选项问题是：
“明天我们去哪里？”
选项：
“图书馆”
“公园”

你的问题是：
1.玩家重新选择后，问题题目改变成：“我们明天不去哪里？”

2.选项改变：
“学校”
“呆在家里”

但都可以新建个标签（label），里面是改变后不同内容的选项（menu）就可以了啊。
https://doc.renpy.cn/zh-CN/quickstart.html#menu-labeljump

要么是二周目用的？那就用变量，而且是持久化数据（persistent）。
https://doc.renpy.cn/zh-CN/persistent.html#persistent-data

不管怎样，萌新建议将文档从头到尾看一遍。

龙氏

示例脚本：

[RenPy] 纯文本查看 复制代码

# 游戏在此开始。
label start:

# 定义变量
    $ XXX = "明天去哪里玩？"
    $ rebirth = False
    $ frequency = 0 # 计数变量。

label A_menu:

    "[XXX]"

    menu:
        "图书馆":
            if rebirth: # 条件判断
                jump park # 脚本跳转到 label park 公园处。
            else :
                jump library # 脚本跳转到 label library 图书馆处。

        "公园":
            if rebirth:
                jump library # 脚本跳转到 label library 图书馆处。
            else :
                jump park # 脚本跳转到 label park 公园处。

        "我好像出不去了？" if frequency >= 3:
            jump Detach # 脚本跳转到 label Detach处。



label library:
    "这里是 图书馆"

    $ XXX = "我们明天不去哪里？" # 改变变量内容。
    $ rebirth = True# 如果变量rebirth为真。
    $ frequency = frequency+1 # 计数+1。

    "重新选择?"
    jump A_menu # 脚本跳转到 label A_menu处。

label park:
    "这里是 公园"

    $ XXX = "我们明天不去哪里？" # 改变变量内容。
    $ rebirth = True# 如果变量rebirth为真。
    $ frequency = frequency+1 # 计数+1。

    "重新选择?"
    jump A_menu

label Detach:
    "啊，脱离轮回之苦！"

    # 此处为游戏结尾。
    return