某个人物说话时，其他人物立绘暗的组件

frost

[RenPy] 纯文本查看 复制代码

transform dark_in:
        matrixcolor Matrix([ 1, 0, 0, 0,
                              0, 1, 0, 0,
                              0, 0, 1, 0,
                              0, 0, 0, 1.0, ])

transform dark:
        matrixcolor Matrix([ 0.7, 0, 0, 0,
                              0, 0.7, 0, 0,
                              0, 0, 0.7, 0,
                              0, 0, 0, 1.0, ])

define speak_character = set(['jr'])

define disableDark = False


init -1 python:
    from functools import partial
    def show(name, isDark=False):
        at_ls = set(renpy.get_at_list(name))
        at_ls = at_ls - set([dark, dark_in])

        if isDark:
            at_ls.add(dark)
        else:
            at_ls.add(dark_in)

        renpy.show(name, at_list=at_ls)

    def char_fade(character_name, event_name, *args, **kwargs):
        if disableDark:
            return

        if event_name == "begin":
            showing_character = speak_character & renpy.get_showing_tags()
            if character_name in showing_character:
                show(character_name)
            showing_character.discard(character_name)
            for chara in showing_character:
                show(chara, True)

        if event_name == "end":
            showing_character = speak_character & renpy.get_showing_tags()
            for chara in showing_character:
                show(chara)

基于这个帖子，修改了部分代码而来，之前他的代码用着还是有不顺手的地方

说明一下，对于需要立绘变暗的角色，需要加入到speak_character 里面，并且角色定义的时候要添加回调函数

frost

可能使用组件会有点卡，可以用啊变量看情况禁用

sqq

感谢大佬！那个请问能不能给个speak_character和角色定义添加回调函数的样例，不知道哪里没写对就是跑不起来

zsc2015

大佬能给一个在脚本中调用这个效果的实际范例吗？
我也是不知道哪里没写对总是跑不起来进不去游戏

zferic

可找到了，就是小白暂时还没看懂！

蓦永寒青

[RenPy] 纯文本查看 复制代码

define xiao = Character("晓莹",callback=partial(char_fade, "xy"))
define ji = Character("纪雨",callback=partial(char_fade, "jy"))

define speak_character = set(['jy','xy'])

角色定义添加回调函数的样例,今天终于试出来的。谢谢大佬分享。
jy,xy是立绘图片名，不知道这样用对不对