[教程] 带时间限制的选项

blackpineapple

本教程二改官网cookbook
[color=var(--text1)]https://www.renpy.org/wiki/renpy/doc/cookbook/Timed_menus


代码如下

[RenPy] 纯文本查看 复制代码

label start:
    scene bg meadow
    show screen countdown(t=5, timer_range=50, timer_jump='menu1_slow')
    menu:
        "选项1":
            hide screen countdown
            "你选择了选项1"

        "选项2":
            hide screen countdown
            "你选择了选项2"
    jump menu1_end
    return

label menu1_slow:
    "时间结束了，你没有选择任何选项。"
    return

label menu1_end:
    "你选择了选项，演示结束。"
    return

transform alpha_dissolve:
    alpha 0.0
    linear 0.5 alpha 1.0
    on hide:
        linear 0.5 alpha 0

## t 一个数值，是倒计时的总秒数，e.g. 5
## timer_range 一个数值，是bar的最大数值。
## timer_jump 一个字符串，时间结束后跳到什么地方的字符串。
screen countdown(t, timer_range, timer_jump):
    default time = t
    ## 每0.1秒，自动减少time0.1
    timer 0.1 repeat True action If(time > 0, true=SetScreenVariable('time', time - 0.1), false=[Hide('countdown'), Jump(timer_jump)])
    ## time*10， 因为bar显示小数并不好，所以这里做了乘以10变成了整数变化。
    bar value time*10 range timer_range xalign 0.5 yalign 0.9 xmaximum 300 at alpha_dissolve

anyuwanqing

感谢分享 最开始那个t=5是什么，是50秒所以是5吗

blackpineapple

anyuwanqing 发表于 2022-7-9 13:57
感谢分享 最开始那个t=5是什么，是50秒所以是5吗

t = 5 是5s。
下面的time *10 是因为，比如时间是4.5s 和时间是4.1s，最后bar其实是不变的，所以*10让他变成45和41，这样bar才会变化。

白洛珩

太感谢大佬了