怎么做到下图右边列表一样的东西，怎么为每个角色随机...

老司机飞飞飞

左边属性栏，右边列表
怎么做出右边的列表
怎么做到一个角色有一个属性列表，而且属性的数值怎么让他随机
就是有几个人，点换一批，然后就刷新出新的人

龙氏

老司机飞飞飞 发表于 2019-2-21 18:43
哦，我慢慢研究

[RenPy] 纯文本查看 复制代码

screen aaa(x,y):

    default a1_name = renpy.random.choice(['周一', '王二', '张三', '李四', '刘五', '赵六', '田七'])
    default a1_Star = renpy.random.randint(1, 3)
    if a1_Star == 1:
        default a1_grade = renpy.random.randint(1, 3)
        default a1_charm = renpy.random.randint(10, 30)
        default a1_gold = renpy.random.randint(10, 100)
    if a1_Star == 2:
        default a1_grade = renpy.random.randint(4, 6)
        default a1_charm = renpy.random.randint(40, 60)
        default a1_gold = renpy.random.randint(200, 600)
    if a1_Star == 3:
        default a1_grade = renpy.random.randint(7, 10)
        default a1_charm = renpy.random.randint(70, 100)
        default a1_gold = renpy.random.randint(800, 1000)

    frame:
        pos (x,y)
        vbox:
            spacing 5
            text "人物卡"
            text "姓名：[a1_name]"
            text "品阶：[a1_Star]"
            textbutton "查看详细属性" action ShowTransient("bbb",transition=dissolve,name=a1_name,aa=a1_grade ,bb=a1_charm ,cc=a1_gold)
    #transclude

screen bbb(name,aa,bb,cc):
    tag m123
    frame:
        align (0.2,0.2) 
        vbox:
            spacing 10
            text "[name]：各项属性值"
            text "级别：[aa]"
            text "魅力：[bb]"
            text "金币：[cc]"
            textbutton "关闭" action Hide("bbb")
    #transclude

screen ccc():
    #tag m123
    on "show" action Notify("已刷新人物卡")
    vbox:
        xpos 0.6
        spacing 5
        use aaa(0.8, 0.1)
        use aaa(0.8, 0.5)
        use aaa(0.8, 0.9)

    textbutton "生成新人物卡":
        pos (0.5, 0.8)
        action Hide("ccc"),Show("ccc")

    textbutton "退出":
        pos (0.9, 0.1)
        action Hide("ccc"),Jump("fff")

# 游戏在此开始。
label start:

    "演示开始"

    call screen ccc with dissolve

label fff:
    "演示结束"

    # 此处为游戏结尾。
    return

龙氏

随机数生成器renpy.random：https://doc.renpy.cn/zh-CN/other ... random#renpy-random
界面(screens)：https://doc.renpy.cn/zh-CN/screens.html
界面动作(action)、值(value)和函数：https://doc.renpy.cn/zh-CN/screen_actions.html

老司机飞飞飞

龙氏 发表于 2019-2-20 18:43
随机数生成器renpy.random：https://doc.renpy.cn/zh-CN/other.html?highlight=renpy%20random#renpy-random
...

哦，我慢慢研究

老司机飞飞飞

龙氏 发表于 2019-2-23 15:12
[mw_shl_code=renpy,true]
screen aaa(x,y):

谢谢大佬

zyq43825

学习到了！谢谢！