按钮（button）如何获焦后平滑移动位置

bell

当图片按钮获取焦点，即鼠标悬停在图片按钮上时，按钮Y坐标上移一点位置，耗时0.5秒的平滑移动，按钮失去焦点时，即鼠标离开图片按钮上时，再平滑移动原来位置。
似乎是如何用 hovered 触发 transform效果？
也可以是图片变大，并不是用 idle，hover切换个大点按钮图片。

龙氏

关键知识：on语句：https://doc.renpy.cn/zh-CN/atl.html#on

[RenPy] 纯文本查看 复制代码

# 定义图像(image)
image Red = "#FF0000" # 注意大小由容器决定。
image Green = "#2a5200"

transform button_a:
    pos (0.2 , 0.4)# 固定位置
    on idle:# 待机时显示
        linear 0.15 ypos 0.4
    on hover:# 鼠标悬停显示
        linear 0.15 ypos 0.3

transform button_b:

    ## 注意 pos、anchor及align三者差别。
    align (0.6 , 0.6)
    #pos (0.6 , 0.6)
    #anchor (0.6 , 0.6)

    on idle:# 待机时显示
        linear 0.15 zoom 1
    on hover:# 鼠标悬停显示
        linear 0.15 zoom 1.2

screen aaa:
    button:
        xsize 170 ysize 240 # 按钮的大小.
        at button_a # 
        add "Red"  # 添加颜色到整个按钮容器。
        hovered Notify(_("你的鼠标悬停在按钮上")) #当按钮获取焦点时运行的动作。
        unhovered Notify(_("鼠标从按钮上离开")) #当按钮失去焦点时运行的动作。
        action NullAction # NullAction语句

    imagebutton:
        xsize 170 ysize 240 # 按钮的大小.
        at button_b # 
        #add "red"  # 添加颜色
        idle "Red"
        hover "Green"
        action NullAction 

# 游戏在此开始。
label start:

    call screen aaa

    # 此处为游戏结尾。
    return

pos：相对坐标，以整个区域左上角为原点。
https://doc.renpy.cn/zh-CN/atl.h ... nsform-property-pos

anchor：锚点坐标，以可视组件左上角为原点。锚点坐标，以可视组件左上角为原点。
https://doc.renpy.cn/zh-CN/atl.h ... orm-property-anchor

align：将pos和anchor设置为相同的值。将pos和anchor设置为相同的值。
https://doc.renpy.cn/zh-CN/atl.h ... form-property-align

NullAction语句：https://doc.renpy.cn/zh-CN/scree ... ighlight#NullAction